package {
 
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.PixelSnapping;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	public class Main extends Sprite {
 
		public function Main() {
			var target:Sprite = new Sprite();
 
			//ライブラリ内の「Cloud」ビットマップクラス（透過PNG）インスタンスを作成
			var bitmap_data:BitmapData = new Cloud();
			var bitmap:Bitmap = new Bitmap(bitmap_data, PixelSnapping.NEVER, true);
			target.addChild(bitmap);
			stage.addChild(target);
			setBitmapRollOverOut(target, bitmap_data, targetOverTest, targetOutTest);
		}
 
		//ロールオーバー時
		private function targetOverTest(target:*):void {
			target.buttonMode = true;
			target.alpha = 0.5;
		}
 
		//ロールアウト時
		private function targetOutTest(target:*):void {
			target.buttonMode = false;
			target.alpha = 1;
		}
 
		//引数にロールオーバー時、ロールアウト時の関数を渡します
		private function setBitmapRollOverOut(target:Object, bitmap_data:BitmapData, rolloverFunction:Function, rolloutFunction:Function):void {
			var color:uint = 0;
			target.addEventListener(Event.ENTER_FRAME, targetOverEnter);
 
			function targetOverEnter(event:Event):void {
 
				//マウス位置のビットマップの（アルファ値を含む）ピクセル色を測定
				color = bitmap_data.getPixel32(target.mouseX, target.mouseY);
 
				//ビットマップが透明でなければロールオーバー関数を実行
				if (color != 0) {
 
					//ロールオーバー関数の実行を一度だけにするため、一旦エンターフレームを解除します
					//同時にロールアウトのエンターフレームを再開します
					target.removeEventListener(Event.ENTER_FRAME, targetOverEnter);
					target.addEventListener(Event.ENTER_FRAME, targetOutEnter);
					rolloverFunction(target);
				}
			}
 
			function targetOutEnter(event:Event):void {
 
				//マウス位置のビットマップの（アルファ値を含む）ピクセル色を測定
				color = bitmap_data.getPixel32(target.mouseX, target.mouseY);
 
				//ビットマップが透明だったらロールアウト関数を実行
				if (color == 0) {
 
					//ロールアウト関数の実行を一度だけにするため、一旦エンターフレームを解除します
					//同時にロールオーバーのエンターフレームを再開します
					target.addEventListener(Event.ENTER_FRAME, targetOverEnter);
					target.removeEventListener(Event.ENTER_FRAME, targetOutEnter);
					rolloutFunction(target);
				}
			}
		}
	}
}

var xml:XML =
<root>
	<item id="1">
		<name>test1</name>
		<url>www.example1.com</url>
	</item>
	<item id="2">
		<name>test2</name>
		<url>www.example2.com</url>
	</item>
	<item id="3">
		<name>test3</name>
	</item>
</root>;
 
//一つ目（0番目）の「item」ノード内の「name」ノードの内容を取得
trace(xml.item[0].name)
//test1
 
//二つ目の「item」ノードの「id」属性を取得
trace(xml.child("item")[1].@id)
//2
 
//「item」ノードの数を取得
trace(xml.item.length());
//3
 
//「item」ノード内の「url」ノードの数を取得
trace(xml.item..url.length());
//2
 
//一つ目（0番目）の「item」ノードの二つ目（1番目）のノード名を取得
trace(xml.item[0].child(1).name());
//url
 
//「item」ノード内の「name」ノードの内容が「test1」の「url」ノードの内容を取得
trace(xml.item.(name == "test1").url);
//www.example1.com
 
//「item」ノード内の「id」属性が「2」の「url」ノードの内容を取得
trace(xml.item.(@id == 2).url)
//www.example2.com
 
//三つ目（2番目）の「item」ノードに「url」ノードの有無をブール値で取得
trace(xml.item[2].hasOwnProperty("url"));
//false

var date:Date = new Date();
var days:Array = new Array();
var today:String = new String();
days = ["sun", "mon", "tue", "wed", "thu", "fri", "sat"];
today = date.fullYear+"/"+(date.month+1)+"/"+date.date+"("+days[date.day]+")";
trace(today);//2011/1/9(sun)

package {
 
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;	
	import flash.system.ApplicationDomain;
	import flash.text.AntiAliasType;
	import flash.text.Font;
	import flash.text.TextField;
	import flash.text.TextFormat;
 
	public class Main extends Sprite {
 
		public function Main() {
			var loader:Loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
			loader.load(new URLRequest("fonts.swf"));
 
			function onComplete(event:Event):void {
				var domain:ApplicationDomain = loader.contentLoaderInfo.applicationDomain;
				var HelveticaRegular:Class = domain.getDefinition("HelveticaRegular") as Class;
				var field:TextField = new TextField();
				var format:TextFormat = new TextFormat();
				var helvetica_regular:Font = new HelveticaRegular();
				Font.registerFont(HelveticaRegular);
				format.font = helvetica_regular.fontName;
				field.defaultTextFormat = format;
				field.embedFonts = true;
				field.antiAliasType = AntiAliasType.ADVANCED;
				field.text = "Font embedded via external swf file.";
				stage.addChild(field);
			}
		}
	}
}

var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
loader.load(new URLRequest("fonts.swf"));

var domain:ApplicationDomain = loader.contentLoaderInfo.applicationDomain;
var HelveticaRegular:Class = domain.getDefinition("HelveticaRegular") as Class;

Font.registerFont(HelveticaRegular);

format.font = helvetica_regular.fontName;

field.embedFonts = true;

field.antiAliasType = AntiAliasType.ADVANCED;

var object:Object = new Object();
object[0] = "りんご";
object[1] = "ばなな";
object["integer"] = 10;
object["array"] = new  Array("test1", "test2");
 
//キーを生成
for (var key:* in object) {
	trace(key);
}
 
//値を生成
for each (var value:* in object) {
	trace(value);
}

//for-inの場合
0
1
array
integer
 
//for each-inの場合
りんご
ばなな
test1,test2
10

for (var key:* in object) {
	trace(key);
	trace(object[key]);
}

import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;
 
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.addEventListener(Event.RESIZE, resizeWindow);
 
function resizeWindow() {
	//ウィンドウがリサイズされた際の処理
}

package {
 
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.PixelSnapping;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.net.URLRequest;	
	import caurina.transitions.Tweener;
	import caurina.transitions.properties.DisplayShortcuts;  
	DisplayShortcuts.init();  
 
	[SWF(width="800", height="600", frameRate="30", backgroundColor="0xffffff")]
 
	public class Main extends Sprite {
 
		public function Main() {
 
			//スライス元のイメージを読み込み
			var loader:Loader = new Loader();
			var info:LoaderInfo = loader.contentLoaderInfo;
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaded);
			loader.load(new URLRequest("image.jpg"));
 
			//読み込みが完了したとき
			function onLoaded(event:Event):void {
				var bmd_base:BitmapData = new BitmapData(info.width, info.height, true);
				var param:Object = new Object();
				bmd_base.draw(loader);
 
				//X軸・Y軸の分割数と、ピースの横幅・縦幅
				param.x = 8;
				param.y = 6;
				param.w = 100;
				param.h = 100;
 
				//Y軸のループ
				for (var i:uint = 0; i < param.y; i++) {
 
					//X軸のループ
					for (var j:uint = 0; j < param.x; j++) {
						var place:Sprite = new Sprite();
						var rect:Rectangle = new Rectangle(param.w*j, param.h*i, param.w, param.h);
						var bmd:BitmapData = new BitmapData(param.w, param.h, true);
						var bm:Bitmap = new Bitmap();
 
						//元のイメージから切り抜き
						bmd.copyPixels(bmd_base, rect, new Point());
						bm.bitmapData = bmd;
						bm.pixelSnapping = PixelSnapping.NEVER;
						bm.smoothing = true;
 
						//ピースの原点を左上から中心に移動
						bm.x = -param.w/2;
						bm.y = -param.h/2;
						place.x = param.w*j+param.w/2;
						place.y = param.h*i+param.h/2;
 
						place.addChild(bm);
						stage.addChild(place);
 
						//透明度、スケールを、それぞれ0から100％にアニメーション
						Tweener.addTween(place, {alpha:0, _scale:0});
						Tweener.addTween(place, {delay:((param.y*i)+j)*0.1, time:0.5, alpha:1, _scale:1});
					}
				}
			}
		}
	}
}

package {
 
	import flash.display.Sprite;
	import caurina.transitions.Tweener;
	import caurina.transitions.properties.TextShortcuts;  
	TextShortcuts.init(); //テキストショートカットを初期化
 
	public class Main extends Sprite {
 
		public function Main() {
			var types:String = "Tweenerを利用すると、簡単にテキストを一文字ずつ表示することができます。";
 
			//2秒間でtypesのテキストを一文字ずつ表示
			Tweener.addTween(text_field, {time:2, _text:types, transition:"linear"});
		}
	}
}

package {
 
	import flash.events.Event;
	import flash.net.URLLoader;	
	import flash.net.URLRequest;	
	import flash.net.URLRequestMethod;
	import flash.net.URLVariables;
	import flash.text.TextField;
 
	public class Main extends Sprite {
 
		public function Main() {
			var url_variables:URLVariables = new URLVariables();
			var url_request:URLRequest = new URLRequest("functions.php");
			var loader:URLLoader = new URLLoader();
 
			//PHPリクエストのPOST変数にPHPの関数名を含める
			url_variables.function_name = "test";
			url_request.method = URLRequestMethod.POST;
			url_request.data = url_variables;
 
			//PHPを実行（読み込み）
			loader.addEventListener(Event.COMPLETE, onComplete);
			loader.load(url_request);
 
			//PHPの実行が完了したとき
			function onComplete(event:Event):void {
 
				//テキストフィールドを作成して、PHP関数の出力を表示
				var textfield:TextField = new TextField();
				stage.addChild(textfield);
				textfield.text = event.target.data;
			}
		}
	}
}

<?php
 
//POST変数「function_name」の関数が存在したら実行
$function = $_POST['function_name'];
if (function_exists($function)) $function();
 
function test() {
 
	//文字列を出力（ActionScriptに渡す）
	echo "function test";
}
?>

setButton(button, "test");
 
//ボタンにロールオーバー、ロールアウト、クリックの設定
function setButton(button:DisplayObject, str:String):void {
	button.addEventListener(MouseEvent.ROLL_OVER, mouseEvent);
	button.addEventListener(MouseEvent.ROLL_OUT, mouseEvent);
	button.addEventListener(MouseEvent.CLICK, mouseEvent);
 
	//イベントのタイプで処理を振り分け
	function mouseEvent(event:MouseEvent):void {
		switch (event.type) {
			case "rollOver": //ロールオーバーのとき
				button.alpha = 0.5;
				trace(str+"over");
				break;
			case "rollOut": //ロールアウトのとき
				button.alpha = 1;
				trace(str+"out");
				break;
			case "click": //クリックのとき
				button.alpha = 0;
				trace(str+"click");
				break;
		}
	}
}

stage.addEventListener(MouseEvent.CLICK, mouseClick("test"));
 
function mouseClick(str:String = null):Function {
	return function(event:MouseEvent):void {
 
		//クリックされたときの処理
		trace(str);
	}
}

function mouseClick(str:String = null):Function {
	return mouseEvent;
 
	function mouseEvent(event:MouseEvent):void {
 
		//クリックされたときの処理
		trace(str);
	}
}

var array_01:Array = new Array(1, 2, 3, 4, 5, 6, 7, 8, 9, 10);
var array_02:Array = array_01.slice(); //array_01を複製
 
shuffleArray(array_02); //シャッフルを実行
 
trace(array_01); //1,2,3,4,5,6,7,8,9,10
trace(array_02); //3,2,10,4,6,8,1,7,9,5
 
//配列をランダムにソートしてシャッフル
function shuffleArray(array:Array):void {
	array.sort(function () {
		return Math.floor(Math.random()*3)-1;
	});
}

package {
 
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import caurina.transitions.Tweener;
 
	public class Main extends Sprite {
 
		public function Main() {
			var piece:Rectangle = new Rectangle(0, 0, 800, 600); //ページのサイズ
			var current:Point = new Point(0, 0); //フィールド内のページ位置
			var pivot:Sprite = new Sprite(); //ステージの中心点
			var field:Sprite = new Sprite();
			pivot.addChild(field);
			stage.addChild(pivot);
			setPivot(pivot);
 
			//ステージのスケールを固定で、原点を左上に
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			//横15×縦10のページでフィールドを作成
			makeField(new Point(15, 10));
 
			//フィールドを作成
			function makeField(grid:Point):void {
				for (var i:uint = 0; i < grid.y; i++) {
					for (var j:uint = 0; j < grid.x; j++) {
 
						//ページに矩形を描きランダムに彩色
						var shape:Shape = new Shape;
						shape.x = piece.width*j-piece.width/2;
						shape.y = piece.height*i-piece.height/2;
						shape.graphics.beginFill(Math.random()*0x1000000);
						shape.graphics.drawRect(piece.x, piece.y, piece.width, piece.height);
						shape.graphics.endFill();
						field.addChild(shape);
					}
				}
				stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyPress(grid));
			}
 
			//方向キーでスクロールの設定
			function onKeyPress(grid:Point):Function {
				return function(event:KeyboardEvent):void {
					switch (event.keyCode) {
						case 37: current.x--; break; //左キー
						case 38: current.y--; break; //上キー
						case 39: current.x++; break; //右キー
						case 40: current.y++; break; //下キー
					}
 
					//フィールドの端まで移動したとき
					if (current.x < 0) current.x = 0;
					if (current.x >= grid.x) current.x = grid.x-1;
					if (current.y < 0) current.y = 0;
					if (current.y >= grid.y) current.y = grid.y-1;
 
					Tweener.addTween(field, {time:0.75, x:-piece.width*current.x, y:-piece.height*current.y});
				}
			}
 
			//ステージサイズに合わせて中心点を移動
			function setPivot(pivot:Sprite):void {
				stage.addEventListener(Event.RESIZE, transfield);
				transfield();
 
				function transfield():void {
					Tweener.addTween(pivot, {time:0.75, x:stage.stageWidth/2, y:stage.stageHeight/2});
				}
			}
		}
	}
}

<script type="text/javascript">
function flashTrace($str) {
alert($str);
}
</script>

ExternalInterface.call("flashTrace", "デバッグのテスト");

ft("デバッグのテスト");
 
function ft(str:String):void {
 
	//サーバへのアクセスを判定してJavascript、またはtraceを実行
	if (loaderInfo.url.indexOf("http") == 0) {
		ExternalInterface.call("flashTrace", str);
	} else {
		trace(str);
	}
}

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>jQuery FLASH</title>
<script type="text/javascript" src="jquery-1.3.2.min.js"></script>
<script type="text/javascript" src="jquery.flash.js"></script>
<script type="text/javascript">
 
$(document).ready(function() {
$('div#flash').flash({'src':'main.swf', 'width':'800', 'height':'400'});
});
 
</script>
</head>
<body>
 
<div id="flash">
<p>このページのコンテンツには、Adobe Flash Playerの最新バージョンが必要です。</p>
</div><!-- flash -->
 
</body>
</html>

<script type="text/javascript" src="jquery-1.3.2.min.js"></script>
<script type="text/javascript" src="jquery.flash.js"></script>
<script type="text/javascript">
 
$(document).ready(function() {
$('div#flash').flash({'src':'main.swf', 'width':'800', 'height':'400'});
});
 
</script>

$('div#flash').flash({'src':'main.swf', 'width':'800', 'height':'400', 'flashvars':{'init':'init.xml', 'image':'image.jpg'}});

package {
 
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.PixelSnapping;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.net.URLRequest;	
 
	public class Main extends Sprite {
 
		public function Main() {
			var loader:Loader = new Loader();
			var info:LoaderInfo = loader.contentLoaderInfo;
 
			//ビットマップデータの読み込み
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
			loader.load(new URLRequest("image.jpg"));
 
			//ステージのスケールを固定で、原点を左上に
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			//ビットマップの読み込みが完了した時
			function onComplete(event:Event):void {
				var bmd:BitmapData = new BitmapData(info.width, info.height);
				var bm:Bitmap = new Bitmap(bmd, PixelSnapping.NEVER, true);
 
				//ビットマップを描画
				bmd.draw(loader);
				stage.addChild(bm);
				adjustBitmap(bm);
			}
 
			//ビットマップをステージのサイズに合わせる
			function adjustBitmap(bm:Bitmap):void {
				var inner:Number = bm.width/bm.height; //ビットマップの縦横比
				var outer:Number; //ステージの縦横比
 
				//ステージのサイズが変更された時
				stage.addEventListener(Event.RESIZE, transSize);
				transSize();
 
				//ビットマップを拡大・縮小
				function transSize():void {
					var size_x:uint = stage.stageWidth;
					var size_y:uint = stage.stageHeight;
 
					outer = size_x/size_y;
 
					//ビットマップ、ステージの縦横比を比較してサイズを変更
					if (inner >= outer) {
						size_x = size_x*(inner/outer);
					} else {
						size_y = size_y*(outer/inner);
					}
					bm.width = size_x;
					bm.height = size_y;
				}
			}
		}
	}
}